Initial dot-file commit after setting up repo and playing with stow

2021-01-19 21:01:53 +01:00
commit c4eefe82ac
1201 changed files with 112139 additions and 0 deletions
@@ -0,0 +1,45 @@
+# sudo
+
+Easily prefix your current or previous commands with `sudo` by pressing <kbd>esc</kbd> twice
+
+To use it, add `sudo` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... sudo)
+```
+
+## Usage
+
+### Current typed commands
+
+Say you have typed a long command and forgot to add `sudo` in front:
+
+```console
+$ apt-get install build-essential
+```
+
+By pressing the <kbd>esc</kbd> key twice, you will have the same command with `sudo` prefixed without typing:
+
+```console
+$ sudo apt-get install build-essential
+```
+
+### Previous executed commands
+
+Say you want to delete a system file and denied:
+
+```console
+$ rm some-system-file.txt
+-su: some-system-file.txt: Permission denied
+$
+```
+
+By pressing the <kbd>esc</kbd> key twice, you will have the same command with `sudo` prefixed without typing:
+
+```console
+$ rm some-system-file.txt
+-su: some-system-file.txt: Permission denied
+$ sudo rm some-system-file.txt
+Password:
+$
+```
@@ -0,0 +1,46 @@
+# ------------------------------------------------------------------------------
+# Description
+# -----------
+#
+# sudo or sudoedit will be inserted before the command
+#
+# ------------------------------------------------------------------------------
+# Authors
+# -------
+#
+# * Dongweiming <ciici123@gmail.com>
+#
+# ------------------------------------------------------------------------------
+
+sudo-command-line() {
+    [[ -z $BUFFER ]] && LBUFFER="$(fc -ln -1)"
+    if [[ -n $EDITOR && $BUFFER == $EDITOR\ * ]]; then
+        if [[ ${#LBUFFER} -le ${#EDITOR} ]]; then
+            RBUFFER=" ${BUFFER#$EDITOR }"
+            LBUFFER="sudoedit"
+        else
+            LBUFFER="sudoedit ${LBUFFER#$EDITOR }"
+        fi
+    elif [[ $BUFFER == sudoedit\ * ]]; then
+        if [[ ${#LBUFFER} -le 8 ]]; then
+            RBUFFER=" ${BUFFER#sudoedit }"
+            LBUFFER="$EDITOR"
+        else
+            LBUFFER="$EDITOR ${LBUFFER#sudoedit }"
+        fi
+    elif [[ $BUFFER == sudo\ * ]]; then
+        if [[ ${#LBUFFER} -le 4 ]]; then
+            RBUFFER="${BUFFER#sudo }"
+            LBUFFER=""
+        else
+            LBUFFER="${LBUFFER#sudo }"
+        fi
+    else
+        LBUFFER="sudo $LBUFFER"
+    fi
+}
+zle -N sudo-command-line
+# Defined shortcut keys: [Esc] [Esc]
+bindkey -M emacs '\e\e' sudo-command-line
+bindkey -M vicmd '\e\e' sudo-command-line
+bindkey -M viins '\e\e' sudo-command-line